Angelyne....
I'll post my new notes soon which will hopefully be helpful for you.
There is some commonality between the various versions with regards to the setup arguments and MSI properties.
I managed to get Creator 2011 Pro installing silently with the features I wanted using the following but I'm working on a more robust solution. I tried splitting out and installing the various MSI's individually in the same order but there must have been setup.exe logic that was being missed as the Roxio Central wasing showing everything correctly. What Roxio Central displays is quite configurable via xml files but I decided to abort that track for a better overall solution.
Here's my script.... (NOTE: This was for testing only. Use for reference not for prod. e.g. This doesn't have good error trapping to pass back to SCCM/SMS/Alteris/etc)
'==========================================================================
'
' NAME: install.vbs
' AUTHOR: Captain Feathersword - 'Arrrghh... Hang 'im from the yardarm'
' DATE : 24/08/2011
' PURPOSE: Installs Roxio Creator 2011 Pro
' APP NAME: Sonic Solutions Roxio Creator 2011 Pro
' PREREQUSITES: .NET 3.5 SP1
' DirextX v9
' MSXML 4.0 Parser
' INSTALLS: Sonic Solutions Roxio Creator 2011 Pro
'==========================================================================
Option Explicit
'On Error Resume Next
Dim oShell, oFSO, oDictionary, scriptReturnCode, tempDir, flagFile, windir
Dim LogPath, scriptname, scriptpath, RemoveOldVersions, oldProdCodes, retVal, app
Dim allusersprofile
Set oShell = CreateObject("WScript.Shell")
Set oFSO = CreateObject("Scripting.FileSystemObject")
Set oDictionary= CreateObject("Scripting.Dictionary")
' Get Relative Path
scriptname = WScript.ScriptFullName
scriptpath = oFSO.GetParentFolderName(scriptname)
' Get Temp and Windows Directories
tempDir = addBackslash(oShell.ExpandEnvironmentStrings("%TEMP%"))
windir = addBackslash(oShell.ExpandEnvironmentStrings("%windir%"))
allusersprofile = addBackslash(oShell.ExpandEnvironmentStrings("%allusersprofile%"))
' Set Logging Path
LogPath = windir & "Debug\"
' Run the installation
oShell.CurrentDirectory = scriptpath
'Check for Roxio Central installed... If not, continue with setup.exe
If IsInstalled("{77CDA026-3860-4C95-8233-34F3CEF121FB}") = False Then
retVal = oShell.Run ("setup.exe SETUPLANG=ENU FORCE_ENCRYPTION=0 ARCHITECTURE=86 NO_ONLINE_ACCESS=1 ROX_KEYTEXT=xx-xxxxx-xxxxx-xxxxx REBOOT=ReallySuppress ALLUSERS=1 ROOTDRIVE=C:\ /qn /l*v " _
& LogPath & "Roxio_Creator_2001_Pro.log",,True)
WScript.Sleep(4000)
Else
WScript.Quit
End If
If oFSO.FileExists(allusersprofile & "\Desktop\Roxio Creator 2011 Pro.lnk") Then
oFSO.DeleteFile allusersprofile & "\Desktop\Roxio Creator 2011 Pro.lnk", True
End If
' Uninstall products not needed
oDictionary.Add "Roxio CinePlayer","{A9024A22-FB0E-4DDC-AB93-44D686F7F491}"
oDictionary.Add "Roxio BackOnTrack","{729B89D0-946A-407E-A121-343BD3320C40}"
oDictionary.Add "Roxio BackOnTrackPE","{BD3EAE4D-862D-4D41-8BB5-F5C2CFFE6022}"
oDictionary.Add "CinePlayer Decoder Pack","{FFAC39DA-CF79-434B-A6E0-4055689667D9}"
oDictionary.Add "SmartSound Quicktracks 5","{2F8BA3FD-1FA9-4279-B696-712ABB12F09F}"
oDictionary.Add "SmartSound Common Data","{B8A2869E-30CA-40C5-9CF8-BD7354E57EF8}"
oDictionary.Add "Roxio Streamer Desktop Applications","{F38406EE-EB4C-449E-B0EF-6887CA988124}"
oDictionary.Add "Roxio Streamer","{B44C746E-2A9E-4184-9FF8-7A44FCA749CE}"
oDictionary.Add "Roxio Video Capture USB","{86DDDAAD-AEB9-42E5-BE01-0E8FABD2BB29}"
oDictionary.Add "Google Toolbar","{18455581-E099-4BA8-BC6B-F34B2F06600C}"
For Each app In oDictionary.Keys
RemoveMSI app, oDictionary.Item(app)
Next
Set oShell = Nothing
Set oFSO = Nothing
WScript.Quit
' Is the windows installer product installed True/False
Function IsInstalled(sProductCode)
On Error Resume Next
Dim RegVal
Err.Clear
RegVal = oShell.RegRead ("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\" & sProductCode & "\DisplayName")
If Err.Number <> 0 Then
IsInstalled = False
Err.Clear
Exit Function
End If
If Len(RegVal) < 1 Then
IsInstalled = False
Exit Function
End If
IsInstalled = True
End Function
Function addBackslash(sString)
On Error Resume Next
If Right(sString,1) = "\" Then
addBackslash = sString
Else
addBackslash = sString & "\"
End If
End Function
Sub RemoveMSI(ProductName,ProductCode)
On Error Resume Next
If IsInstalled(ProductCode) = True Then
oShell.Run "msiexec /x " & ProductCode & " REBOOT=ReallySuppress /qn /l*v """ & LogPath & ProductName & "_uninstall.log""",,True
WScript.Sleep 2000
End If
End Sub
I then set a few per user settings such as...
[HKEY_CURRENT_USER\Software\Roxio\HomeUtils\{4433FF9E-AF21-4E41-B296-4E13BF4D52F5}]
"ShowEULA"=dword:00000000
[HKEY_CURRENT_USER\Software\Roxio\EMC13\Creator Classic\11.0\Settings]
"UseWindowsTemp"=dword:00000001
But like I said above, I wasn't happy with this so I'm trying a different tact with different software. I'll let you know how I get on.
3
